osmfeatures/build.gradle.kts at master · westnordost/osmfeatures · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
import com.android.build.api.dsl.androidLibrary

plugins {
    id("org.jetbrains.kotlin.multiplatform") version "2.4.0"
    id("com.android.kotlin.multiplatform.library") version "8.12.3"
    id("com.vanniktech.maven.publish") version "0.37.0"
    id("org.jetbrains.dokka") version "2.2.0"
}

group = "de.westnordost"
version = "8.0.0"

kotlin {
    jvm()

    androidLibrary {
        namespace = "de.westnordost.osmfeatures"
        compileSdk = 36
        minSdk = 21
    }

    iosSimulatorArm64()
    iosArm64()

    applyDefaultHierarchyTemplate()

    sourceSets {
        commonMain {
            dependencies {
                // multiplatform file access
                api("org.jetbrains.kotlinx:kotlinx-io-core:0.8.0")
                // parsing the preset.json
                implementation("org.jetbrains.kotlinx:kotlinx-serialization-json:1.11.0")
                implementation("org.jetbrains.kotlinx:kotlinx-serialization-json-io:1.11.0")
                // for stripping diacritics correctly
                implementation("com.doist.x:normalize:1.3.3")
            }
        }
        commonTest {
            dependencies {
                implementation(kotlin("test"))
                // we are pulling some current preset json from the iD preset repo to see if parsing
                // does at least not crash and return something
                implementation("io.ktor:ktor-client-core:3.5.1")
                implementation("io.ktor:ktor-client-cio:3.5.1")
                // ktor-client is a suspending API, so we need coroutines too
                implementation("org.jetbrains.kotlinx:kotlinx-coroutines-core:1.11.0")
            }
        }
    }
}

dokka {
    moduleName.set("osmfeatures")
    dokkaSourceSets {
        configureEach {
            sourceLink {
                remoteUrl("https://github.com/westnordost/osmfeatures/tree/v${project.version}/")
                localDirectory = rootDir
            }
        }
    }
}

mavenPublishing {
    publishToMavenCentral()

    signAllPublications()

    coordinates(group.toString(), rootProject.name, version.toString())

    pom {
        name = "osmfeatures"
        description = "Kotlin multiplatform library to translate OSM tags to and from localized names."
        url = "https://github.com/westnordost/osmfeatures"
        licenses {
            license {
                name = "The Apache License, Version 2.0"
                url = "https://raw.githubusercontent.com/westnordost/osmfeatures/master/LICENSE"
            }
        }
        issueManagement {
            system = "GitHub"
            url = "https://github.com/westnordost/osmfeatures/issues"
        }
        scm {
            connection = "https://github.com/westnordost/osmfeatures.git"
            url = "https://github.com/westnordost/osmfeatures"
            developerConnection = connection
        }
        developers {
            developer {
                id = "westnordost"
                name = "Tobias Zwick"
                email = "osm@westnordost.de"
            }
        }
    }
}